MarkLogic ColumnIFやFORを使った構文

はじめに

本稿では、MarkLogicなどのXMLデータベースに用いられるXQueryの条件分岐に用いるif/else文や基本構文「FLOWR構文」を説明します。

if/elseによる条件分岐

他の一般的なプログラミング言語と同様にXQueryでも条件分岐はif/elseを用います。if/else内の条件には、等号・不等号やブール値を設定することができます。elseは省略できません。変数$birthと2000を比較して文字列を返すサンプルクエリを示します。

let $birth := 2000 (: 変数$birthに整数2000を割り当てる。 :) return ( if($birth < 2000) then ("young") else if($birth = 2000) then ("just") else ("elder") )

XQueryにはswitchもあります。同じ動作のサンプルクエリを示します。

let $birth := 2000 (: 変数$birthに整数2000を割り当てる。 :) return ( switch(fn:true()) case ($birth < 2000) return ("young") case ($birth = 2000) return ("just") default return ("elder") )

この中で使われているlet句やreturn句については次のFLOWR構文の中で紹介します。

FLOWR構文

XQueryを記述するにあたり必要となる５つの構文です。５つの頭文字をとってFLOWRと称します。まずは一覧を示しましょう。

FLOWR文を使った例文

5つの構文全てを使ったXQueryの例文を見てみましょう。「顧客データを参照して2000年以降の顧客データをid要素でソートして返す」という想定です。クエリコンソールのDatabaseをデフォルトで存在する「Documents」、Query Typeを「XQuery」として中部のテキストフィールドにそれぞれ貼り付けて実行します。

まずは３件の顧客データを挿入します。それぞれ誕生年を2001年・2000年・1999年とします。

(: 挿入先のURIの共通部分 :) let $uriHeader := "/customerData/" (: 3個の挿入内容 :) let $node-seq := ( "<customer><id>30</id><name>Abe</name><birth>1999</birth><address>Tokyo</address></customer>", "<customer><id>20</id><name>Bitou</name><birth>2000</birth><address>Shiga</address></customer>", "<customer><id>10</id><name>Chatou</name><birth>2001</birth><address>Saga</address></customer>" ) (: ドキュメントの挿入 :) for $node in $node-seq let $tempNode := xdmp:unquote($node) let $id := $tempNode/customer/id/text() let $uri := fn:concat($uriHeader, $id, ".xml") (: id要素を用いて挿入先を決める :) return xdmp:document-insert($uri, $tempNode)

いよいよ検索クエリです。戻り値をカンマで文字列連結するため、fn:string-join関数を用いています。

let $limitYear := xs:integer(2000) (: 顧客データを取得する。 :) let $doc-seq := cts:search(/*, cts:directory-query("/customerData/")) (: 顧客データそれぞれについて、順番数字・id・名前・誕生年をカンマで文字列連結して返す。 ただし対象は2000年生まれ以降として、id要素の昇順でソートする。:) for $doc at $num in $doc-seq let $result-seq := (xs:string($num), $doc/id/text(), $doc/name/text(), $doc/birth/text()) (: 1個のシーケンスにする :) where xs:integer($doc/birth/text()) >= $limitYear (: 誕生年が2000年以降 :) order by $doc/id (: idの昇順でソート :) return fn:string-join($result-seq, ",") (: カンマで文字列連結 :)

検索結果で2000年と2001年のデータが出ていれば検索成功です。

3,10,Chatou,2001 1,20,Bitou,2000

余裕があれば、where文やorder by文の内容を変更して戻り値がどのように変わるか確認してみて下さい。

FLOWR文の課題とMarkLogicの対応

ここまでFLOWR文を説明してきました。ところで、クエリ上に検索したデータを展開してwhere句による選別やorder by句によるソートを行うと、データ規模によってはforループの負荷が重たくなって時間がかかる可能性があります。これに対してMarkLogicでは索引追加・クエリ修正によって高速化を図ることができます。

ここではwhere句条件のbirth要素とorder by句条件のid要素にPath range indexという索引を設定することによる改善を紹介します。Path range indexとはXPathで指定した範囲を対象とした索引です。以下にPath range indexの設定手順を示します。

1. 1. 管理者画面(ポート8001番)を開きます。
2. 2. 画面左側でDatabaseの「Documents」を選択すると設定項目が展開されます。この中から「Path range indexes」を開いてください。下図は設定画面です。
   
3. 3. 画面上部の「Add」を開くと索引設定画面になります。設定すべき項目を表にしました。「scalar type」をstringにした場合はcollactionを設定しなければいけませんが、今回はデフォルトのままのRoot Collactionとしましょう。

   scalar type	path expression	collaction
   string	/customer/id	Root Collation
   int	/customer/birth	-

4. 4. OKボタンを押せば完了です。リインデックスと呼ばれる索引の再作成が開始されます。データベース内のデータが少量であれば、リインデックスはすぐに完了します。下図は設定後の「Path range indexes」画面です。
   

Path range index設定後のクエリチューニング例を示します。ここではfor句内からwhere句・order by句を削除することができました。今回のデータでは、for句のループは生年が2000年以降の２データのみとなり、order by句によるクエリ内でのソートは不要となっています。

let $limitYear := xs:integer(2000) (: 検索条件の設定 :) let $query := cts:and-query(( cts:directory-query("/customerData/"), cts:path-range-query("/customer/birth", ">=", $limitYear) )) let $option := cts:index-order(cts:path-reference("/customer/id")) (: 顧客データを取得する。 :) let $doc-seq := cts:search(/*, $query, $option) (: 取得した顧客データそれぞれについて、順番数字・id・名前・誕生年をカンマで文字列連結して返す。 :) for $doc at $num in $doc-seq let $result-seq := (xs:string($num), $doc/id/text(), $doc/name/text(), $doc/birth/text()) (: 1個のシーケンスにする :) return fn:string-join($result-seq, ",") (: カンマで文字列連結 :)

まとめ

本稿の内容をまとめます。

• XQueryはMarkLogicをはじめとしたXMLデータベースに対するクエリとして用いられます。
• XQueryは条件分岐にif/elseを用います。elseは省略できません。
• XQueryには、FLWORと呼ばれる基本構文があります。FLOWRとは、「forによる繰り返し」・「letによる代入」・「order byによるソート」・「whereによる選別」・「returnによる戻り値設定」の総称です。
• FLOWR構文のうち、where句とorder by句はクエリ処理が重たくなる可能性があります。MarkLogicでは索引を追加することで高速化を図ることができます。